_realname=jq
pkgname=${_realname}
pkgver=1.8.2
pkgrel=1
pkgdesc="Command-line JSON processor"
arch=('x86_64')
url='https://jqlang.github.io/jq/'
msys2_repository_url="https://github.com/jqlang/jq"
msys2_references=(
  "cpe: cpe:/a:jq_project:jq"
)
license=('spdx:MIT')
depends=('gcc-libs' 'oniguruma')
makedepends=("autotools" "gcc")
source=(
  "https://github.com/jqlang/${_realname}/releases/download/${_realname}-${pkgver}/${_realname}-${pkgver}.tar.gz"
)
sha512sums=('d4058940cff1cd9946d7f2a9057316bf05915679385386685d140b7a82d870d43ae5b5b4d0a5560c864cf0ef2cc59d7b6ed3afb46b3aea0f4d35329678b2c328')

prepare() {
  cd "${pkgname}-${pkgver}"

  # avoid it asking git for the version
  echo "echo ${pkgver}" > scripts/version
  autoreconf -fiv
}

build() {
  cd "${pkgname}-${pkgver}"

  ./configure \
    --prefix=/usr \
    --disable-docs \
    ac_cv_lib_m_scalb=no \
    ac_cv_lib_m_significand=no

  make
}

check() {
  cd "${pkgname}-${pkgver}"
  MSYSTEM=CYGWIN make check
}

package() {
  cd "${pkgname}-${pkgver}"
  make install DESTDIR="${pkgdir}"
}
