# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname=HTTP-Date
pkgname=perl-${_realname}
pkgver=6.07
pkgrel=1
pkgdesc="Date conversion routines"
arch=('any')
license=('spdx:Artistic-1.0-Perl OR GPL-1.0-or-later')
groups=('perl-modules')
options=('!emptydirs')
depends=('perl>=5.8.8')
conflicts=('perl-libwww<6')
url="https://metacpan.org/release/HTTP-Date"
msys2_references=(
  "purl: pkg:cpan/OALDERS/HTTP-Date"
)
source=(https://search.cpan.org/CPAN/authors/id/O/OA/OALDERS/${_realname}-$pkgver.tar.gz)
sha256sums=('278c875a1abae8b3afaf7961c8dfe8ea21b37e04ce8fe3c387e7eb999c1d2128')

build() {
  ( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""                 \
      PERL_AUTOINSTALL=--skipdeps                            \
      PERL_MM_OPT="INSTALLDIRS=vendor"     \
      PERL_MB_OPT="--installdirs vendor" \
      MODULEBUILDRC=/dev/null

    cd "${_realname}-${pkgver}"
    /usr/bin/perl Makefile.PL
    make
  )
}

check() {
  ( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
    cd "${_realname}-${pkgver}"
    make test
  )
}

package() {
  cd "${_realname}-${pkgver}"
  make DESTDIR="$pkgdir" install
}
