# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>

_realname=cryptography
pkgname=python-cryptography
pkgver=48.0.1
pkgrel=1
pkgdesc="A package designed to expose cryptographic recipes and primitives to Python developers"
arch=('i686' 'x86_64')
license=('spdx:Apache-2.0 OR BSD-3-Clause')
url="https://github.com/pyca/cryptography"
msys2_repository_url='https://github.com/pyca/cryptography'
msys2_references=(
  'archlinux: python-cryptography'
  'gentoo: dev-python/cryptography'
  'purl: pkg:pypi/cryptography'
  "cpe: cpe:/a:cryptography:python-cryptography"
  "cpe: cpe:/a:cryptography_project:cryptography"
  "cpe: cpe:/a:python-cryptography_project:python-cryptography"
)
depends=(
  'libopenssl'
  'python'
  'python-cffi'
)
makedepends=(
  'python-build'
  'python-installer'
  'python-maturin'
  'python-setuptools'
  'rust'
  'openssl-devel'
  'pkgconf'
)
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz")
sha256sums=('266f4ee051abb2f725b74ef8072b521ce1feacf685a3364fa6a6b45548db791a')

build() {
  cd "${_realname}-${pkgver}"

  python -m build --wheel --no-isolation
}

package() {
  cd "${_realname}-${pkgver}"

  python -m installer --destdir="$pkgdir" dist/*.whl
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.BSD
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE.APACHE
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
