# Maintainer: Christoph Reiter <reiter.christoph@gmail.com>

_pyname=gi_docgen
pkgname=gi-docgen
pkgver=2025.5
pkgrel=1
pkgdesc="Documentation generator for GObject-based libraries"
url="https://gnome.pages.gitlab.gnome.org/gi-docgen/"
msys2_repository_url="https://gitlab.gnome.org/GNOME/gi-docgen"
msys2_changelog_url='https://gitlab.gnome.org/GNOME/gi-docgen/-/blob/main/CHANGES.md'
msys2_references=(
  'archlinux: gi-docgen'
  'gentoo: dev-util/gi-docgen'
  'purl: pkg:pypi/gi-docgen'
)
arch=(any)
license=("spdx:Apache-2.0 OR GPL-3.0-or-later")
depends=(
  python
  python-jinja
  python-markdown
  python-markupsafe
  python-packaging
  python-pygments
)
makedepends=(
  python-build
  python-installer
  python-setuptools
)
source=("https://pypi.org/packages/source/${_pyname::1}/${_pyname}/${_pyname}-${pkgver}.tar.gz")
sha256sums=('7fb2b5370d99849e52e74e9e584b7eeb5b5a3a95493d6752c88c0d251777f4bf')

build() {
  cd "$_pyname-$pkgver"

  python -m build --wheel --no-isolation
}

package() {
  cd "$_pyname-$pkgver"

  python -m installer --destdir="$pkgdir" dist/*.whl
}
